xref: /6.0.3/ns_server/src/async.erl (revision 1f1b6fc4)
1%% @author Couchbase <info@couchbase.com>
2%% @copyright 2017-2018 Couchbase, Inc.
3%%
4%% Licensed under the Apache License, Version 2.0 (the "License");
5%% you may not use this file except in compliance with the License.
6%% You may obtain a copy of the License at
7%%
8%%      http://www.apache.org/licenses/LICENSE-2.0
9%%
10%% Unless required by applicable law or agreed to in writing, software
11%% distributed under the License is distributed on an "AS IS" BASIS,
12%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
13%% See the License for the specific language governing permissions and
14%% limitations under the License.
15
16-module(async).
17
18-include("cut.hrl").
19-include("ns_common.hrl").
20-include_lib("eunit/include/eunit.hrl").
21
22-export([start/1, start/2,
23         start_many/2, start_many/3,
24         perform/1, perform/2,
25         abort/1, abort/2,
26         abort_many/1, abort_many/2,
27         send/2,
28         with/2, with/3,
29         with_many/3, with_many/4,
30         wait/1, wait/2,
31         wait_many/1, wait_many/2,
32         wait_any/1, wait_any/2,
33         race/2, map/2, foreach/2,
34         run_with_timeout/2,
35         get_identity/0]).
36
37start(Fun) ->
38    start(Fun, []).
39
40start(Fun, Opts) ->
41    SpawnFun =
42        case proplists:get_value(monitor, Opts, false) of
43            true ->
44                fun misc:spawn_monitor/1;
45            false ->
46                fun proc_lib:spawn/1
47        end,
48
49    Parent           = self(),
50    ParentController = get_controller(),
51
52    SpawnFun(
53      fun () ->
54              async_init(Parent, ParentController, Opts, Fun)
55      end).
56
57perform(Fun) ->
58    perform(Fun, [monitor]).
59
60perform(Fun, Opts) ->
61    start(Fun, Opts ++ [{type, perform}]).
62
63start_many(Fun, Args) ->
64    start_many(Fun, Args, []).
65
66start_many(Fun, Args, Opts) ->
67    [start(fun () ->
68                   Fun(A)
69           end, Opts) || A <- Args].
70
71abort(Pid) ->
72    abort_many([Pid]).
73
74abort(Pid, Reason) ->
75    abort_many([Pid], Reason).
76
77abort_many(Pids) ->
78    abort_many(Pids, shutdown).
79
80abort_many(Pids, Reason) ->
81    misc:terminate_and_wait(Pids, Reason).
82
83send(Async, Msg) ->
84    Async ! {'$async_msg', Msg},
85    Msg.
86
87with(AsyncBody, Fun) ->
88    with(AsyncBody, [], Fun).
89
90with(AsyncBody, Opts, Fun) ->
91    Async = start(AsyncBody, Opts),
92    try
93        Fun(Async)
94    after
95        abort(Async)
96    end.
97
98with_many(AsyncBody, Args, Fun) ->
99    with_many(AsyncBody, Args, [], Fun).
100
101with_many(AsyncBody, Args, Opts, Fun) ->
102    Asyncs = start_many(AsyncBody, Args, Opts),
103    try
104        Fun(Asyncs)
105    after
106        abort_many(Asyncs)
107    end.
108
109wait(Pid) ->
110    wait(Pid, []).
111
112wait(Pid, Flags) ->
113    call(Pid, get_result, Flags).
114
115wait_many(Pids) ->
116    wait_many(Pids, []).
117
118wait_many(Pids, Flags) ->
119    call_many(Pids, get_result, Flags).
120
121wait_any(Pids) ->
122    wait_any(Pids, []).
123
124wait_any(Pids, Flags) ->
125    call_any(Pids, get_result, Flags).
126
127race(Fun1, Fun2) ->
128    with(
129      Fun1,
130      fun (Async1) ->
131              with(
132                Fun2,
133                fun (Async2) ->
134                        case wait_any([Async1, Async2]) of
135                            {Async1, R} ->
136                                {left, R};
137                            {Async2, R} ->
138                                {right, R}
139                        end
140                end)
141      end).
142
143map(Fun, List) ->
144    with_many(
145      Fun, List,
146      fun (Asyncs) ->
147              Results = wait_many(Asyncs),
148              [R || {_, R} <- Results]
149      end).
150
151foreach(Fun, List) ->
152    with_many(
153      Fun, List,
154      fun (Asyncs) ->
155              _ = wait_many(Asyncs),
156              ok
157      end).
158
159run_with_timeout(Fun, Timeout) ->
160    case race(Fun, fun () -> receive after Timeout -> timeout end end) of
161        {left, R} ->
162            {ok, R};
163        {right, timeout} ->
164            {error, timeout}
165    end.
166
167get_identity() ->
168    case get_role() of
169        executor ->
170            Controller = get_controller(),
171            true = is_pid(Controller),
172
173            {ok, Controller};
174        _ ->
175            not_async
176    end.
177
178%% internal
179async_init(Parent, ParentController, Opts, Fun) ->
180    erlang:monitor(process, Parent),
181
182    set_role(controller),
183    maybe_register_with_parent_async(ParentController),
184
185    Adopters = proplists:get_value(adopters, Opts, []),
186    lists:foreach(register_for_adoption(_), Adopters),
187
188    process_flag(trap_exit, true),
189
190    Reply      = make_ref(),
191    Controller = self(),
192
193    Child =
194        spawn_link(
195          fun () ->
196                  set_role(executor),
197                  set_controller(Controller),
198
199                  To = {Controller, Reply},
200
201                  try Fun() of
202                      R ->
203                          reply(To, {ok, R})
204                  catch
205                      T:E ->
206                          Stack = erlang:get_stacktrace(),
207                          reply(To, {raised, {T, E, Stack}}),
208                          erlang:raise(T, E, Stack)
209                  end
210          end),
211
212    case proplists:get_value(abort_after, Opts) of
213        undefined ->
214            ok;
215        AbortAfter when is_integer(AbortAfter) ->
216            erlang:send_after(AbortAfter, self(), abort_after_expired)
217    end,
218
219    Type = proplists:get_value(type, Opts, wait),
220    async_loop_wait_result(Type, Child, Reply, []).
221
222maybe_register_with_parent_async(undefined) ->
223    ok;
224maybe_register_with_parent_async(Pid) ->
225    {ok, _} = register_with_async(Pid).
226
227register_with_async(Pid) ->
228    controller = get_role(),
229    case call(Pid, {register_child_async, self()}) of
230        {ok, _} = Ok ->
231            Ok;
232        nack ->
233            ?log_debug("Received nack when trying to register with ~p", [Pid]),
234            exit(normal)
235    end.
236
237async_loop_wait_result(Type, Child, Reply, ChildAsyncs) ->
238    receive
239        {'DOWN', _MRef, process, _Pid, Reason} = Down ->
240            maybe_log_down_message(Down),
241            terminate_now(Child, ChildAsyncs, Reason);
242        {'EXIT', Child, Reason} ->
243            terminate_on_query(Type,
244                               undefined, ChildAsyncs, {child_died, Reason});
245        %% note, we don't assume that this comes from the parent, because we
246        %% can be terminated by parent async, for example, which is not the
247        %% actual parent of our process
248        {'EXIT', _, Reason} ->
249            terminate_now(Child, ChildAsyncs, Reason);
250        {'$async_req', From, {register_child_async, Pid}} ->
251            reply(From, {ok, Child}),
252            async_loop_wait_result(Type, Child, Reply, [Pid | ChildAsyncs]);
253        {Reply, Result} ->
254            async_loop_handle_result(Type, Child, ChildAsyncs, Result);
255        {'$async_msg', Msg} ->
256            Child ! Msg,
257            async_loop_wait_result(Type, Child, Reply, ChildAsyncs);
258        abort_after_expired ->
259            terminate_on_query(Type, Child, ChildAsyncs, timeout)
260    end.
261
262maybe_terminate_child(undefined, _Reason) ->
263    ok;
264maybe_terminate_child(Child, Reason)
265  when is_pid(Child) ->
266    misc:unlink_terminate_and_wait(Child, Reason).
267
268terminate_children(Child, ChildAsyncs, Reason) ->
269    maybe_terminate_child(Child, Reason),
270    misc:terminate_and_wait(ChildAsyncs, Reason).
271
272terminate_now(Child, ChildAsyncs, Reason) ->
273    terminate_children(Child, ChildAsyncs, Reason),
274    exit(Reason).
275
276terminate_on_query(perform, Child, ChildAsyncs, Reason) ->
277    terminate_now(Child, ChildAsyncs, Reason);
278terminate_on_query(wait, Child, ChildAsyncs, Reason) ->
279    terminate_children(Child, ChildAsyncs, Reason),
280    async_loop_with_result({die, Reason}).
281
282async_loop_handle_result(Type, Child, ChildAsyncs, Result) ->
283    unlink(Child),
284    ?flush({'EXIT', Child, _}),
285
286    misc:terminate_and_wait(ChildAsyncs, shutdown),
287
288    case Type of
289        perform ->
290            case Result of
291                {raised, {T, E, Stack}} ->
292                    erlang:raise(T, E, Stack);
293                {ok, _} ->
294                    exit(normal)
295            end;
296        wait ->
297            case Result of
298                {ok, Success} ->
299                    async_loop_with_result({reply, Success});
300                {raised, _} = Raised ->
301                    async_loop_with_result({die, Raised})
302            end
303    end.
304
305-spec async_loop_with_result({die, any()} | {reply, any()}) -> no_return().
306async_loop_with_result(Result) ->
307    receive
308        {'DOWN', _MRef, process, _Pid, Reason} = Down ->
309            maybe_log_down_message(Down),
310            exit(Reason);
311        {'EXIT', _, Reason} ->
312            exit(Reason);
313        {'$async_req', From, get_result} ->
314            handle_get_result(From, Result);
315        {'$async_req', From, {register_child_async, _Pid}} ->
316            %% We don't expect register requests at this point, but it's
317            %% possible to write a correct async that has such behavior. If we
318            %% don't reply, the requesting process will have to wait till we
319            %% die, which is unnecessary. So we just respond with nack to kill
320            %% it quickly.
321            reply(From, nack),
322            async_loop_with_result(Result);
323        {'$async_req', _, _} = Req ->
324            exit({unexpected_request, Req});
325        _ ->
326            async_loop_with_result(Result)
327    end.
328
329handle_get_result(From, {reply, Result}) ->
330    reply(From, Result),
331    exit(normal);
332handle_get_result(_From, {die, Reason}) ->
333    exit(Reason).
334
335call(Pid, Req) ->
336    call(Pid, Req, []).
337
338call(Pid, Req, Flags) ->
339    [{Pid, R}] = call_many([Pid], Req, Flags),
340    R.
341
342call_many(Pids, Req, Flags) ->
343    PidMRefs = monitor_asyncs(Pids),
344    try
345        send_req_many(PidMRefs, Req),
346        recv_many(PidMRefs, Flags)
347    after
348        demonitor_asyncs(PidMRefs)
349    end.
350
351call_any(Pids, Req, Flags) ->
352    PidMRefs = monitor_asyncs(Pids),
353    try
354        send_req_many(PidMRefs, Req),
355        recv_any(PidMRefs, Flags)
356    after
357        Pids = demonitor_asyncs(PidMRefs),
358        abort_many(Pids),
359        drop_extra_resps(PidMRefs)
360    end.
361
362drop_extra_resps(PidMRefs) ->
363    lists:foreach(
364      fun ({_, MRef}) ->
365              ?flush({MRef, _})
366      end, PidMRefs).
367
368reply({Pid, Tag}, Reply) ->
369    Pid ! {Tag, Reply}.
370
371monitor_asyncs(Pids) ->
372    [{Pid, erlang:monitor(process, Pid)} || Pid <- Pids].
373
374demonitor_asyncs(PidMRefs) ->
375    lists:map(
376      fun ({Pid, MRef}) ->
377              erlang:demonitor(MRef, [flush]),
378              Pid
379      end, PidMRefs).
380
381send_req(Pid, MRef, Req) ->
382    Pid ! {'$async_req', {self(), MRef}, Req}.
383
384send_req_many(PidMRefs, Req) ->
385    lists:foreach(
386      fun ({Pid, MRef}) ->
387              send_req(Pid, MRef, Req)
388      end, PidMRefs).
389
390recv_resp(MRef, Interruptible) ->
391    receive
392        {MRef, R} ->
393            R;
394        {'DOWN', MRef, _, _, Reason} ->
395            recv_resp_handle_down(Reason);
396        {'EXIT', _Pid, _Reason} = Exit when Interruptible ->
397            throw({interrupted, Exit})
398    end.
399
400recv_resp_handle_down({raised, {T, E, Stack}}) ->
401    erlang:raise(T, E, Stack);
402recv_resp_handle_down(Reason) ->
403    exit(Reason).
404
405recv_many(PidMRefs, Flags) ->
406    Interruptible = proplists:get_bool(interruptible, Flags),
407    [{Pid, recv_resp(MRef, Interruptible)} || {Pid, MRef} <- PidMRefs].
408
409recv_any(PidMRefs, Flags) ->
410    Interruptible = proplists:get_bool(interruptible, Flags),
411    recv_any_loop(PidMRefs, Interruptible, []).
412
413recv_any_loop(PidMRefs, Interruptible, PendingMsgs) ->
414    receive
415        {Ref, R} = Msg when is_reference(Ref) ->
416            case lists:keyfind(Ref, 2, PidMRefs) of
417                {Pid, Ref} ->
418                    recv_any_loop_resend_pending(PendingMsgs),
419                    {Pid, R};
420                false ->
421                    recv_any_loop(PidMRefs,
422                                  Interruptible,
423                                  [Msg | PendingMsgs])
424            end;
425        {'DOWN', Ref, _, _, Reason} = Msg ->
426            case lists:keymember(Ref, 2, PidMRefs) of
427                true ->
428                    recv_any_loop_resend_pending(PendingMsgs),
429                    recv_resp_handle_down(Reason);
430                false ->
431                    recv_any_loop(PidMRefs,
432                                  Interruptible,
433                                  [Msg | PendingMsgs])
434            end;
435        {'EXIT', _Pid, _Reason} = Exit when Interruptible ->
436            throw({interrupted, Exit})
437    end.
438
439recv_any_loop_resend_pending(PendingMsgs) ->
440    lists:foreach(
441      fun (Msg) ->
442              self() ! Msg
443      end, lists:reverse(PendingMsgs)).
444
445set_role(Role) ->
446    erlang:put('$async_role', Role).
447
448get_role() ->
449    erlang:get('$async_role').
450
451set_controller(Pid) when is_pid(Pid) ->
452    executor = get_role(),
453    erlang:put('$async_controller', Pid).
454
455get_controller() ->
456    erlang:get('$async_controller').
457
458register_for_adoption(Controller) ->
459    {ok, Executor} = register_with_async(Controller),
460    erlang:monitor(process, Executor).
461
462maybe_log_down_message({'DOWN', _MRef, process, Pid, Reason}) ->
463    case misc:is_normal_termination(Reason) of
464        true ->
465            ok;
466        false ->
467            ?log_warning("Monitored process ~p "
468                         "terminated abnormally (reason = ~p)", [Pid, Reason])
469    end.
470
471-ifdef(EUNIT).
472abort_after_test() ->
473    A1 = async:start(?cut(timer:sleep(10000)), [{abort_after, 100}]),
474    ?assertExit(timeout, async:wait(A1)),
475
476    A2 = async:start(?cut(timer:sleep(10000)), [{abort_after, 100}]),
477    timer:sleep(200),
478    ?assertExit(timeout, async:wait(A2)),
479
480    ok = async:with(?cut(timer:sleep(100)),
481                    [{abort_after, 200}], async:wait(_)),
482
483
484    {A3, MRef} = async:perform(?cut(timer:sleep(1000)),
485                               [monitor, {abort_after, 100}]),
486    ?must_flush({'DOWN', MRef, process, A3, timeout}).
487-endif.
488