xref: /6.0.3/ns_server/src/async.erl (revision 5f585c26)
1%% @author Couchbase <info@couchbase.com>
2%% @copyright 2017-2018 Couchbase, Inc.
3%%
4%% Licensed under the Apache License, Version 2.0 (the "License");
5%% you may not use this file except in compliance with the License.
6%% You may obtain a copy of the License at
7%%
8%%      http://www.apache.org/licenses/LICENSE-2.0
9%%
10%% Unless required by applicable law or agreed to in writing, software
11%% distributed under the License is distributed on an "AS IS" BASIS,
12%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
13%% See the License for the specific language governing permissions and
14%% limitations under the License.
15
16-module(async).
17
18-include("cut.hrl").
19-include("ns_common.hrl").
20-include_lib("eunit/include/eunit.hrl").
21
22-export([start/1, start/2,
23         start_many/2, start_many/3,
24         perform/1, perform/2,
25         abort/1, abort/2,
26         abort_many/1, abort_many/2,
27         send/2,
28         with/2, with/3,
29         with_many/3, with_many/4,
30         wait/1, wait/2,
31         wait_many/1, wait_many/2,
32         wait_any/1, wait_any/2,
33         race/2, map/2, foreach/2,
34         run_with_timeout/2,
35         get_identity/0]).
36
37start(Fun) ->
38    start(Fun, []).
39
40start(Fun, Opts) ->
41    SpawnFun =
42        case proplists:get_value(monitor, Opts, false) of
43            true ->
44                fun misc:spawn_monitor/1;
45            false ->
46                fun proc_lib:spawn/1
47        end,
48
49    Parent           = self(),
50    ParentController = get_controller(),
51
52    SpawnFun(
53      fun () ->
54              async_init(Parent, ParentController, Opts, Fun)
55      end).
56
57perform(Fun) ->
58    perform(Fun, [monitor]).
59
60perform(Fun, Opts) ->
61    start(Fun, Opts ++ [{type, perform}]).
62
63start_many(Fun, Args) ->
64    start_many(Fun, Args, []).
65
66start_many(Fun, Args, Opts) ->
67    [start(fun () ->
68                   Fun(A)
69           end, Opts) || A <- Args].
70
71abort(Pid) ->
72    abort_many([Pid]).
73
74abort(Pid, Reason) ->
75    abort_many([Pid], Reason).
76
77abort_many(Pids) ->
78    abort_many(Pids, shutdown).
79
80abort_many(Pids, Reason) ->
81    misc:terminate_and_wait(Pids, Reason).
82
83send(Async, Msg) ->
84    Async ! {'$async_msg', Msg},
85    Msg.
86
87with(AsyncBody, Fun) ->
88    with(AsyncBody, [], Fun).
89
90with(AsyncBody, Opts, Fun) ->
91    Async = start(AsyncBody, Opts),
92    try
93        Fun(Async)
94    after
95        abort(Async)
96    end.
97
98with_many(AsyncBody, Args, Fun) ->
99    with_many(AsyncBody, Args, [], Fun).
100
101with_many(AsyncBody, Args, Opts, Fun) ->
102    Asyncs = start_many(AsyncBody, Args, Opts),
103    try
104        Fun(Asyncs)
105    after
106        abort_many(Asyncs)
107    end.
108
109wait(Pid) ->
110    wait(Pid, []).
111
112wait(Pid, Flags) ->
113    call(Pid, get_result, Flags).
114
115wait_many(Pids) ->
116    wait_many(Pids, []).
117
118wait_many(Pids, Flags) ->
119    call_many(Pids, get_result, Flags).
120
121wait_any(Pids) ->
122    wait_any(Pids, []).
123
124wait_any(Pids, Flags) ->
125    call_any(Pids, get_result, Flags).
126
127race(Fun1, Fun2) ->
128    with(
129      Fun1,
130      fun (Async1) ->
131              with(
132                Fun2,
133                fun (Async2) ->
134                        case wait_any([Async1, Async2]) of
135                            {Async1, R} ->
136                                {left, R};
137                            {Async2, R} ->
138                                {right, R}
139                        end
140                end)
141      end).
142
143map(Fun, List) ->
144    with_many(
145      Fun, List,
146      fun (Asyncs) ->
147              Results = wait_many(Asyncs),
148              [R || {_, R} <- Results]
149      end).
150
151foreach(Fun, List) ->
152    with_many(
153      Fun, List,
154      fun (Asyncs) ->
155              _ = wait_many(Asyncs),
156              ok
157      end).
158
159run_with_timeout(Fun, Timeout) ->
160    case race(Fun, fun () -> receive after Timeout -> timeout end end) of
161        {left, R} ->
162            {ok, R};
163        {right, timeout} ->
164            {error, timeout}
165    end.
166
167get_identity() ->
168    case get_role() of
169        executor ->
170            Controller = get_controller(),
171            true = is_pid(Controller),
172
173            {ok, Controller};
174        _ ->
175            not_async
176    end.
177
178%% internal
179async_init(Parent, ParentController, Opts, Fun) ->
180    erlang:monitor(process, Parent),
181
182    set_role(controller),
183    maybe_register_with_parent_async(ParentController),
184
185    Adopters = proplists:get_value(adopters, Opts, []),
186    lists:foreach(register_for_adoption(_), Adopters),
187
188    process_flag(trap_exit, true),
189
190    Reply      = make_ref(),
191    Controller = self(),
192
193    Child =
194        spawn_link(
195          fun () ->
196                  set_role(executor),
197                  set_controller(Controller),
198
199                  To = {Controller, Reply},
200
201                  try Fun() of
202                      R ->
203                          reply(To, {ok, R})
204                  catch
205                      T:E ->
206                          Stack = erlang:get_stacktrace(),
207                          reply(To, {raised, {T, E, Stack}}),
208                          erlang:raise(T, E, Stack)
209                  end
210          end),
211
212    case proplists:get_value(abort_after, Opts) of
213        undefined ->
214            ok;
215        AbortAfter when is_integer(AbortAfter) ->
216            erlang:send_after(AbortAfter, self(), abort_after_expired)
217    end,
218
219    Type = proplists:get_value(type, Opts, wait),
220    async_loop_wait_result(Type, Child, Reply, []).
221
222maybe_register_with_parent_async(undefined) ->
223    ok;
224maybe_register_with_parent_async(Pid) ->
225    {ok, _} = register_with_async(Pid).
226
227register_with_async(Pid) ->
228    controller = get_role(),
229    {ok, _} = call(Pid, {register_child_async, self()}).
230
231async_loop_wait_result(Type, Child, Reply, ChildAsyncs) ->
232    receive
233        {'DOWN', _MRef, process, _Pid, Reason} = Down ->
234            maybe_log_down_message(Down),
235            terminate_now(Child, ChildAsyncs, Reason);
236        {'EXIT', Child, Reason} ->
237            terminate_on_query(Type,
238                               undefined, ChildAsyncs, {child_died, Reason});
239        %% note, we don't assume that this comes from the parent, because we
240        %% can be terminated by parent async, for example, which is not the
241        %% actual parent of our process
242        {'EXIT', _, Reason} ->
243            terminate_now(Child, ChildAsyncs, Reason);
244        {'$async_req', From, {register_child_async, Pid}} ->
245            reply(From, {ok, Child}),
246            async_loop_wait_result(Type, Child, Reply, [Pid | ChildAsyncs]);
247        {Reply, Result} ->
248            async_loop_handle_result(Type, Child, ChildAsyncs, Result);
249        {'$async_msg', Msg} ->
250            Child ! Msg,
251            async_loop_wait_result(Type, Child, Reply, ChildAsyncs);
252        abort_after_expired ->
253            terminate_on_query(Type, Child, ChildAsyncs, timeout)
254    end.
255
256maybe_terminate_child(undefined, _Reason) ->
257    ok;
258maybe_terminate_child(Child, Reason)
259  when is_pid(Child) ->
260    misc:unlink_terminate_and_wait(Child, Reason).
261
262terminate_children(Child, ChildAsyncs, Reason) ->
263    maybe_terminate_child(Child, Reason),
264    misc:terminate_and_wait(ChildAsyncs, Reason).
265
266terminate_now(Child, ChildAsyncs, Reason) ->
267    terminate_children(Child, ChildAsyncs, Reason),
268    exit(Reason).
269
270terminate_on_query(perform, Child, ChildAsyncs, Reason) ->
271    terminate_now(Child, ChildAsyncs, Reason);
272terminate_on_query(wait, Child, ChildAsyncs, Reason) ->
273    terminate_children(Child, ChildAsyncs, Reason),
274    async_loop_with_result({die, Reason}).
275
276async_loop_handle_result(Type, Child, ChildAsyncs, Result) ->
277    unlink(Child),
278    ?flush({'EXIT', Child, _}),
279
280    misc:terminate_and_wait(ChildAsyncs, shutdown),
281
282    case Type of
283        perform ->
284            case Result of
285                {raised, {T, E, Stack}} ->
286                    erlang:raise(T, E, Stack);
287                {ok, _} ->
288                    exit(normal)
289            end;
290        wait ->
291            case Result of
292                {ok, Success} ->
293                    async_loop_with_result({reply, Success});
294                {raised, _} = Raised ->
295                    async_loop_with_result({die, Raised})
296            end
297    end.
298
299async_loop_with_result(Result) ->
300    receive
301        {'DOWN', _MRef, process, _Pid, Reason} = Down ->
302            maybe_log_down_message(Down),
303            exit(Reason);
304        {'EXIT', _, Reason} ->
305            exit(Reason);
306        {'$async_req', From, get_result} ->
307            handle_get_result(From, Result);
308        {'$async_req', From, {register_child_async, _Pid}} ->
309            %% We don't expect register requests at this point, but it's
310            %% possible to write a correct async that has such behavior. If we
311            %% don't reply, the requesting process will have to wait till we
312            %% die, which is unnecessary. So we just respond with nack to kill
313            %% it quickly.
314            reply(From, nack);
315        {'$async_req', _, _} = Req ->
316            exit({unexpected_request, Req});
317        _ ->
318            async_loop_with_result(Result)
319    end.
320
321handle_get_result(From, {reply, Result}) ->
322    reply(From, Result);
323handle_get_result(_From, {die, Reason}) ->
324    exit(Reason).
325
326call(Pid, Req) ->
327    call(Pid, Req, []).
328
329call(Pid, Req, Flags) ->
330    [{Pid, R}] = call_many([Pid], Req, Flags),
331    R.
332
333call_many(Pids, Req, Flags) ->
334    PidMRefs = monitor_asyncs(Pids),
335    try
336        send_req_many(PidMRefs, Req),
337        recv_many(PidMRefs, Flags)
338    after
339        demonitor_asyncs(PidMRefs)
340    end.
341
342call_any(Pids, Req, Flags) ->
343    PidMRefs = monitor_asyncs(Pids),
344    try
345        send_req_many(PidMRefs, Req),
346        recv_any(PidMRefs, Flags)
347    after
348        Pids = demonitor_asyncs(PidMRefs),
349        abort_many(Pids),
350        drop_extra_resps(PidMRefs)
351    end.
352
353drop_extra_resps(PidMRefs) ->
354    lists:foreach(
355      fun ({_, MRef}) ->
356              ?flush({MRef, _})
357      end, PidMRefs).
358
359reply({Pid, Tag}, Reply) ->
360    Pid ! {Tag, Reply}.
361
362monitor_asyncs(Pids) ->
363    [{Pid, erlang:monitor(process, Pid)} || Pid <- Pids].
364
365demonitor_asyncs(PidMRefs) ->
366    lists:map(
367      fun ({Pid, MRef}) ->
368              erlang:demonitor(MRef, [flush]),
369              Pid
370      end, PidMRefs).
371
372send_req(Pid, MRef, Req) ->
373    Pid ! {'$async_req', {self(), MRef}, Req}.
374
375send_req_many(PidMRefs, Req) ->
376    lists:foreach(
377      fun ({Pid, MRef}) ->
378              send_req(Pid, MRef, Req)
379      end, PidMRefs).
380
381recv_resp(MRef, Interruptible) ->
382    receive
383        {MRef, R} ->
384            R;
385        {'DOWN', MRef, _, _, Reason} ->
386            recv_resp_handle_down(Reason);
387        {'EXIT', _Pid, _Reason} = Exit when Interruptible ->
388            throw({interrupted, Exit})
389    end.
390
391recv_resp_handle_down({raised, {T, E, Stack}}) ->
392    erlang:raise(T, E, Stack);
393recv_resp_handle_down(Reason) ->
394    exit(Reason).
395
396recv_many(PidMRefs, Flags) ->
397    Interruptible = proplists:get_bool(interruptible, Flags),
398    [{Pid, recv_resp(MRef, Interruptible)} || {Pid, MRef} <- PidMRefs].
399
400recv_any(PidMRefs, Flags) ->
401    Interruptible = proplists:get_bool(interruptible, Flags),
402    recv_any_loop(PidMRefs, Interruptible, []).
403
404recv_any_loop(PidMRefs, Interruptible, PendingMsgs) ->
405    receive
406        {Ref, R} = Msg when is_reference(Ref) ->
407            case lists:keyfind(Ref, 2, PidMRefs) of
408                {Pid, Ref} ->
409                    recv_any_loop_resend_pending(PendingMsgs),
410                    {Pid, R};
411                false ->
412                    recv_any_loop(PidMRefs,
413                                  Interruptible,
414                                  [Msg | PendingMsgs])
415            end;
416        {'DOWN', Ref, _, _, Reason} = Msg ->
417            case lists:keymember(Ref, 2, PidMRefs) of
418                true ->
419                    recv_any_loop_resend_pending(PendingMsgs),
420                    recv_resp_handle_down(Reason);
421                false ->
422                    recv_any_loop(PidMRefs,
423                                  Interruptible,
424                                  [Msg | PendingMsgs])
425            end;
426        {'EXIT', _Pid, _Reason} = Exit when Interruptible ->
427            throw({interrupted, Exit})
428    end.
429
430recv_any_loop_resend_pending(PendingMsgs) ->
431    lists:foreach(
432      fun (Msg) ->
433              self() ! Msg
434      end, lists:reverse(PendingMsgs)).
435
436set_role(Role) ->
437    erlang:put('$async_role', Role).
438
439get_role() ->
440    erlang:get('$async_role').
441
442set_controller(Pid) when is_pid(Pid) ->
443    executor = get_role(),
444    erlang:put('$async_controller', Pid).
445
446get_controller() ->
447    erlang:get('$async_controller').
448
449register_for_adoption(Controller) ->
450    {ok, Executor} = register_with_async(Controller),
451    erlang:monitor(process, Executor).
452
453maybe_log_down_message({'DOWN', _MRef, process, Pid, Reason}) ->
454    case misc:is_normal_termination(Reason) of
455        true ->
456            ok;
457        false ->
458            ?log_warning("Monitored process ~p "
459                         "terminated abnormally (reason = ~p)", [Pid, Reason])
460    end.
461
462-ifdef(EUNIT).
463abort_after_test() ->
464    A1 = async:start(?cut(timer:sleep(10000)), [{abort_after, 100}]),
465    ?assertExit(timeout, async:wait(A1)),
466
467    A2 = async:start(?cut(timer:sleep(10000)), [{abort_after, 100}]),
468    timer:sleep(200),
469    ?assertExit(timeout, async:wait(A2)),
470
471    ok = async:with(?cut(timer:sleep(100)),
472                    [{abort_after, 200}], async:wait(_)),
473
474
475    {A3, MRef} = async:perform(?cut(timer:sleep(1000)),
476                               [monitor, {abort_after, 100}]),
477    ?must_flush({'DOWN', MRef, process, A3, timeout}).
478-endif.
479