xref: /6.0.3/ns_server/src/async.erl (revision 7f64b87e)
1%% @author Couchbase <info@couchbase.com>
2%% @copyright 2017-2018 Couchbase, Inc.
3%%
4%% Licensed under the Apache License, Version 2.0 (the "License");
5%% you may not use this file except in compliance with the License.
6%% You may obtain a copy of the License at
7%%
8%%      http://www.apache.org/licenses/LICENSE-2.0
9%%
10%% Unless required by applicable law or agreed to in writing, software
11%% distributed under the License is distributed on an "AS IS" BASIS,
12%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
13%% See the License for the specific language governing permissions and
14%% limitations under the License.
15
16-module(async).
17
18-include("cut.hrl").
19-include("ns_common.hrl").
20-include_lib("eunit/include/eunit.hrl").
21
22-export([start/1, start/2,
23         start_many/2, start_many/3,
24         perform/1, perform/2,
25         abort/1, abort/2,
26         abort_many/1, abort_many/2,
27         send/2,
28         with/2, with/3,
29         with_many/3, with_many/4,
30         wait/1, wait/2,
31         wait_many/1, wait_many/2,
32         wait_any/1, wait_any/2,
33         race/2, map/2, foreach/2,
34         run_with_timeout/2,
35         get_identity/0]).
36
37start(Fun) ->
38    start(Fun, []).
39
40start(Fun, Opts) ->
41    SpawnFun =
42        case proplists:get_value(monitor, Opts, false) of
43            true ->
44                fun misc:spawn_monitor/1;
45            false ->
46                fun proc_lib:spawn/1
47        end,
48
49    Parent           = self(),
50    ParentController = get_controller(),
51
52    SpawnFun(
53      fun () ->
54              async_init(Parent, ParentController, Opts, Fun)
55      end).
56
57perform(Fun) ->
58    perform(Fun, [monitor]).
59
60perform(Fun, Opts) ->
61    start(Fun, Opts ++ [{type, perform}]).
62
63start_many(Fun, Args) ->
64    start_many(Fun, Args, []).
65
66start_many(Fun, Args, Opts) ->
67    [start(fun () ->
68                   Fun(A)
69           end, Opts) || A <- Args].
70
71abort(Pid) ->
72    abort_many([Pid]).
73
74abort(Pid, Reason) ->
75    abort_many([Pid], Reason).
76
77abort_many(Pids) ->
78    abort_many(Pids, shutdown).
79
80abort_many(Pids, Reason) ->
81    misc:terminate_and_wait(Pids, Reason).
82
83send(Async, Msg) ->
84    Async ! {'$async_msg', Msg},
85    Msg.
86
87with(AsyncBody, Fun) ->
88    with(AsyncBody, [], Fun).
89
90with(AsyncBody, Opts, Fun) ->
91    Async = start(AsyncBody, Opts),
92    try
93        Fun(Async)
94    after
95        abort(Async)
96    end.
97
98with_many(AsyncBody, Args, Fun) ->
99    with_many(AsyncBody, Args, [], Fun).
100
101with_many(AsyncBody, Args, Opts, Fun) ->
102    Asyncs = start_many(AsyncBody, Args, Opts),
103    try
104        Fun(Asyncs)
105    after
106        abort_many(Asyncs)
107    end.
108
109wait(Pid) ->
110    wait(Pid, []).
111
112wait(Pid, Flags) ->
113    call(Pid, get_result, Flags).
114
115wait_many(Pids) ->
116    wait_many(Pids, []).
117
118wait_many(Pids, Flags) ->
119    call_many(Pids, get_result, Flags).
120
121wait_any(Pids) ->
122    wait_any(Pids, []).
123
124wait_any(Pids, Flags) ->
125    call_any(Pids, get_result, Flags).
126
127race(Fun1, Fun2) ->
128    with(
129      Fun1,
130      fun (Async1) ->
131              with(
132                Fun2,
133                fun (Async2) ->
134                        case wait_any([Async1, Async2]) of
135                            {Async1, R} ->
136                                {left, R};
137                            {Async2, R} ->
138                                {right, R}
139                        end
140                end)
141      end).
142
143map(Fun, List) ->
144    with_many(
145      Fun, List,
146      fun (Asyncs) ->
147              Results = wait_many(Asyncs),
148              [R || {_, R} <- Results]
149      end).
150
151foreach(Fun, List) ->
152    with_many(
153      Fun, List,
154      fun (Asyncs) ->
155              _ = wait_many(Asyncs),
156              ok
157      end).
158
159run_with_timeout(Fun, Timeout) ->
160    case race(Fun, fun () -> receive after Timeout -> timeout end end) of
161        {left, R} ->
162            {ok, R};
163        {right, timeout} ->
164            {error, timeout}
165    end.
166
167get_identity() ->
168    case get_role() of
169        executor ->
170            Controller = get_controller(),
171            true = is_pid(Controller),
172
173            {ok, Controller};
174        _ ->
175            not_async
176    end.
177
178%% internal
179async_init(Parent, ParentController, Opts, Fun) ->
180    erlang:monitor(process, Parent),
181
182    set_role(controller),
183    maybe_register_with_parent_async(ParentController),
184
185    Adopters = proplists:get_value(adopters, Opts, []),
186    lists:foreach(register_for_adoption(_), Adopters),
187
188    process_flag(trap_exit, true),
189
190    Reply      = make_ref(),
191    Controller = self(),
192
193    Child =
194        spawn_link(
195          fun () ->
196                  set_role(executor),
197                  set_controller(Controller),
198
199                  To = {Controller, Reply},
200
201                  try Fun() of
202                      R ->
203                          reply(To, {ok, R})
204                  catch
205                      T:E ->
206                          Stack = erlang:get_stacktrace(),
207                          reply(To, {raised, {T, E, Stack}}),
208                          erlang:raise(T, E, Stack)
209                  end
210          end),
211
212    case proplists:get_value(abort_after, Opts) of
213        undefined ->
214            ok;
215        AbortAfter when is_integer(AbortAfter) ->
216            erlang:send_after(AbortAfter, self(), abort_after_expired)
217    end,
218
219    Type = proplists:get_value(type, Opts, wait),
220    async_loop_wait_result(Type, Child, Reply, []).
221
222maybe_register_with_parent_async(undefined) ->
223    ok;
224maybe_register_with_parent_async(Pid) ->
225    {ok, _} = register_with_async(Pid).
226
227register_with_async(Pid) ->
228    controller = get_role(),
229    {ok, _} = call(Pid, {register_child_async, self()}).
230
231async_loop_wait_result(Type, Child, Reply, ChildAsyncs) ->
232    receive
233        {'DOWN', _MRef, process, _Pid, Reason} = Down ->
234            maybe_log_down_message(Down),
235            terminate_now(Child, ChildAsyncs, Reason);
236        {'EXIT', Child, Reason} ->
237            terminate_on_query(Type,
238                               undefined, ChildAsyncs, {child_died, Reason});
239        %% note, we don't assume that this comes from the parent, because we
240        %% can be terminated by parent async, for example, which is not the
241        %% actual parent of our process
242        {'EXIT', _, Reason} ->
243            terminate_now(Child, ChildAsyncs, Reason);
244        {'$async_req', From, {register_child_async, Pid}} ->
245            reply(From, {ok, Child}),
246            async_loop_wait_result(Type, Child, Reply, [Pid | ChildAsyncs]);
247        {Reply, Result} ->
248            async_loop_handle_result(Type, Child, ChildAsyncs, Result);
249        {'$async_msg', Msg} ->
250            Child ! Msg,
251            async_loop_wait_result(Type, Child, Reply, ChildAsyncs);
252        abort_after_expired ->
253            terminate_on_query(Type, Child, ChildAsyncs, timeout)
254    end.
255
256maybe_terminate_child(undefined, _Reason) ->
257    ok;
258maybe_terminate_child(Child, Reason)
259  when is_pid(Child) ->
260    misc:unlink_terminate_and_wait(Child, Reason).
261
262terminate_children(Child, ChildAsyncs, Reason) ->
263    maybe_terminate_child(Child, Reason),
264    misc:terminate_and_wait(ChildAsyncs, Reason).
265
266terminate_now(Child, ChildAsyncs, Reason) ->
267    terminate_children(Child, ChildAsyncs, Reason),
268    exit(Reason).
269
270terminate_on_query(perform, Child, ChildAsyncs, Reason) ->
271    terminate_now(Child, ChildAsyncs, Reason);
272terminate_on_query(wait, Child, ChildAsyncs, Reason) ->
273    terminate_children(Child, ChildAsyncs, Reason),
274    async_loop_with_result({die, Reason}).
275
276async_loop_handle_result(Type, Child, ChildAsyncs, Result) ->
277    unlink(Child),
278    ?flush({'EXIT', Child, _}),
279
280    misc:terminate_and_wait(ChildAsyncs, shutdown),
281
282    case Type of
283        perform ->
284            case Result of
285                {raised, {T, E, Stack}} ->
286                    erlang:raise(T, E, Stack);
287                {ok, _} ->
288                    exit(normal)
289            end;
290        wait ->
291            case Result of
292                {ok, Success} ->
293                    async_loop_with_result({reply, Success});
294                {raised, _} = Raised ->
295                    async_loop_with_result({die, Raised})
296            end
297    end.
298
299-spec async_loop_with_result({die, any()} | {reply, any()}) -> no_return().
300async_loop_with_result(Result) ->
301    receive
302        {'DOWN', _MRef, process, _Pid, Reason} = Down ->
303            maybe_log_down_message(Down),
304            exit(Reason);
305        {'EXIT', _, Reason} ->
306            exit(Reason);
307        {'$async_req', From, get_result} ->
308            handle_get_result(From, Result);
309        {'$async_req', From, {register_child_async, _Pid}} ->
310            %% We don't expect register requests at this point, but it's
311            %% possible to write a correct async that has such behavior. If we
312            %% don't reply, the requesting process will have to wait till we
313            %% die, which is unnecessary. So we just respond with nack to kill
314            %% it quickly.
315            reply(From, nack);
316        {'$async_req', _, _} = Req ->
317            exit({unexpected_request, Req});
318        _ ->
319            async_loop_with_result(Result)
320    end.
321
322handle_get_result(From, {reply, Result}) ->
323    reply(From, Result),
324    exit(normal);
325handle_get_result(_From, {die, Reason}) ->
326    exit(Reason).
327
328call(Pid, Req) ->
329    call(Pid, Req, []).
330
331call(Pid, Req, Flags) ->
332    [{Pid, R}] = call_many([Pid], Req, Flags),
333    R.
334
335call_many(Pids, Req, Flags) ->
336    PidMRefs = monitor_asyncs(Pids),
337    try
338        send_req_many(PidMRefs, Req),
339        recv_many(PidMRefs, Flags)
340    after
341        demonitor_asyncs(PidMRefs)
342    end.
343
344call_any(Pids, Req, Flags) ->
345    PidMRefs = monitor_asyncs(Pids),
346    try
347        send_req_many(PidMRefs, Req),
348        recv_any(PidMRefs, Flags)
349    after
350        Pids = demonitor_asyncs(PidMRefs),
351        abort_many(Pids),
352        drop_extra_resps(PidMRefs)
353    end.
354
355drop_extra_resps(PidMRefs) ->
356    lists:foreach(
357      fun ({_, MRef}) ->
358              ?flush({MRef, _})
359      end, PidMRefs).
360
361reply({Pid, Tag}, Reply) ->
362    Pid ! {Tag, Reply}.
363
364monitor_asyncs(Pids) ->
365    [{Pid, erlang:monitor(process, Pid)} || Pid <- Pids].
366
367demonitor_asyncs(PidMRefs) ->
368    lists:map(
369      fun ({Pid, MRef}) ->
370              erlang:demonitor(MRef, [flush]),
371              Pid
372      end, PidMRefs).
373
374send_req(Pid, MRef, Req) ->
375    Pid ! {'$async_req', {self(), MRef}, Req}.
376
377send_req_many(PidMRefs, Req) ->
378    lists:foreach(
379      fun ({Pid, MRef}) ->
380              send_req(Pid, MRef, Req)
381      end, PidMRefs).
382
383recv_resp(MRef, Interruptible) ->
384    receive
385        {MRef, R} ->
386            R;
387        {'DOWN', MRef, _, _, Reason} ->
388            recv_resp_handle_down(Reason);
389        {'EXIT', _Pid, _Reason} = Exit when Interruptible ->
390            throw({interrupted, Exit})
391    end.
392
393recv_resp_handle_down({raised, {T, E, Stack}}) ->
394    erlang:raise(T, E, Stack);
395recv_resp_handle_down(Reason) ->
396    exit(Reason).
397
398recv_many(PidMRefs, Flags) ->
399    Interruptible = proplists:get_bool(interruptible, Flags),
400    [{Pid, recv_resp(MRef, Interruptible)} || {Pid, MRef} <- PidMRefs].
401
402recv_any(PidMRefs, Flags) ->
403    Interruptible = proplists:get_bool(interruptible, Flags),
404    recv_any_loop(PidMRefs, Interruptible, []).
405
406recv_any_loop(PidMRefs, Interruptible, PendingMsgs) ->
407    receive
408        {Ref, R} = Msg when is_reference(Ref) ->
409            case lists:keyfind(Ref, 2, PidMRefs) of
410                {Pid, Ref} ->
411                    recv_any_loop_resend_pending(PendingMsgs),
412                    {Pid, R};
413                false ->
414                    recv_any_loop(PidMRefs,
415                                  Interruptible,
416                                  [Msg | PendingMsgs])
417            end;
418        {'DOWN', Ref, _, _, Reason} = Msg ->
419            case lists:keymember(Ref, 2, PidMRefs) of
420                true ->
421                    recv_any_loop_resend_pending(PendingMsgs),
422                    recv_resp_handle_down(Reason);
423                false ->
424                    recv_any_loop(PidMRefs,
425                                  Interruptible,
426                                  [Msg | PendingMsgs])
427            end;
428        {'EXIT', _Pid, _Reason} = Exit when Interruptible ->
429            throw({interrupted, Exit})
430    end.
431
432recv_any_loop_resend_pending(PendingMsgs) ->
433    lists:foreach(
434      fun (Msg) ->
435              self() ! Msg
436      end, lists:reverse(PendingMsgs)).
437
438set_role(Role) ->
439    erlang:put('$async_role', Role).
440
441get_role() ->
442    erlang:get('$async_role').
443
444set_controller(Pid) when is_pid(Pid) ->
445    executor = get_role(),
446    erlang:put('$async_controller', Pid).
447
448get_controller() ->
449    erlang:get('$async_controller').
450
451register_for_adoption(Controller) ->
452    {ok, Executor} = register_with_async(Controller),
453    erlang:monitor(process, Executor).
454
455maybe_log_down_message({'DOWN', _MRef, process, Pid, Reason}) ->
456    case misc:is_normal_termination(Reason) of
457        true ->
458            ok;
459        false ->
460            ?log_warning("Monitored process ~p "
461                         "terminated abnormally (reason = ~p)", [Pid, Reason])
462    end.
463
464-ifdef(EUNIT).
465abort_after_test() ->
466    A1 = async:start(?cut(timer:sleep(10000)), [{abort_after, 100}]),
467    ?assertExit(timeout, async:wait(A1)),
468
469    A2 = async:start(?cut(timer:sleep(10000)), [{abort_after, 100}]),
470    timer:sleep(200),
471    ?assertExit(timeout, async:wait(A2)),
472
473    ok = async:with(?cut(timer:sleep(100)),
474                    [{abort_after, 200}], async:wait(_)),
475
476
477    {A3, MRef} = async:perform(?cut(timer:sleep(1000)),
478                               [monitor, {abort_after, 100}]),
479    ?must_flush({'DOWN', MRef, process, A3, timeout}).
480-endif.
481